cmake_minimum_required(VERSION 3.20)
project(LinSurf VERSION 0.9.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

# Linux: dağıtım paketleri, FreeBSD: pkg install qt6-base qt6-webengine
# (Qt, /usr/local/lib/cmake altında bulunur; FreeBSD'de ek ayar gerekmez.)
find_package(Qt6 6.5 REQUIRED COMPONENTS Widgets WebEngineWidgets Network WebEngineCore WebChannel)
find_package(Threads REQUIRED)

# Şifre kasası şifrelemesi: libsodium (FreeBSD: pkg install libsodium pkgconf)
find_package(PkgConfig REQUIRED)
pkg_check_modules(SODIUM REQUIRED IMPORTED_TARGET libsodium>=1.0.18)
qt_standard_project_setup()

qt_add_executable(linsurf
    src/main.cpp
    src/MainWindow.cpp
    src/MainWindow.h
    src/BrowserView.cpp
    src/BrowserView.h
    src/QuietWebPage.cpp
    src/QuietWebPage.h
    src/AdBlocker.cpp
    src/AdBlocker.h
    src/VaultCrypto.cpp
    src/VaultCrypto.h
    src/PasswordVault.cpp
    src/PasswordVault.h
    src/PasswordManager.cpp
    src/PasswordManager.h
    src/PasswordBridge.cpp
    src/PasswordBridge.h
    src/PasswordDialogs.cpp
    src/PasswordDialogs.h
    src/SingleInstance.cpp
    src/SingleInstance.h
    src/DefaultBrowser.cpp
    src/DefaultBrowser.h
    src/AboutDialog.cpp
    src/AboutDialog.h
)

# Pencere / alt bar simgesi programın içine gömülür.
set(LINSURF_ICON_SIZES 16 24 32 48 64 128 256)
set(LINSURF_ICON_FILES)
foreach(size IN LISTS LINSURF_ICON_SIZES)
    list(APPEND LINSURF_ICON_FILES icons/linsurf-${size}.png)
endforeach()
qt_add_resources(linsurf linsurf_icons
    PREFIX /
    FILES ${LINSURF_ICON_FILES}
)

# Arayüz simgeleri (araç çubuğu, sekme kapatma, menü işaretleri); @2x
# sürümleri yüksek DPI ekranlarda Qt tarafından otomatik seçilir.
file(GLOB LINSURF_THEME_FILES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} CONFIGURE_DEPENDS theme/*/*.png)
qt_add_resources(linsurf linsurf_theme
    PREFIX /
    FILES ${LINSURF_THEME_FILES}
)

# Sayfaya enjekte edilen betikler
qt_add_resources(linsurf linsurf_scripts
    PREFIX /
    FILES scripts/passwords.js
)

target_compile_definitions(linsurf PRIVATE LINSURF_VERSION="${PROJECT_VERSION}")

target_link_libraries(linsurf PRIVATE
    Qt6::Widgets
    Qt6::WebEngineWidgets Qt6::Network
    Qt6::WebEngineCore
    Qt6::WebChannel
    PkgConfig::SODIUM
    Threads::Threads
)

install(TARGETS linsurf RUNTIME DESTINATION bin)

# Uygulama menüsü girdisi ve tema simgeleri (hicolor)
install(FILES linsurf.desktop DESTINATION share/applications)
foreach(size IN LISTS LINSURF_ICON_SIZES)
    install(FILES icons/linsurf-${size}.png
            DESTINATION share/icons/hicolor/${size}x${size}/apps
            RENAME linsurf.png)
endforeach()
install(FILES icons/linsurf.svg DESTINATION share/icons/hicolor/scalable/apps)

# Menülerin yeni simgeyi hemen görmesi için önbellekleri yenile (araç yoksa sessizce geç).
install(CODE [[
    if(NOT DEFINED ENV{DESTDIR} OR "$ENV{DESTDIR}" STREQUAL "")
        execute_process(COMMAND gtk-update-icon-cache -q -t -f "${CMAKE_INSTALL_PREFIX}/share/icons/hicolor"
                        RESULT_VARIABLE _r OUTPUT_QUIET ERROR_QUIET)
        execute_process(COMMAND update-desktop-database -q "${CMAKE_INSTALL_PREFIX}/share/applications"
                        RESULT_VARIABLE _r OUTPUT_QUIET ERROR_QUIET)
    endif()
]])
